설명3D-Link.PNG	Two curves with linking number 4. L8a14. Created with POV-Ray.
날짜	2007년 9월 7일, 06:56 (원본 올리기 일시)
출처	en.wikipedia에서 공용으로 옮겨왔습니다. by Keyi (토론 · 기여).
저자	Jim.belk
저작권 (이 파일을 인용하기)	Public domainPublic domainfalsefalse   이 작품은 위키미디어 공용의 Jim.belk 사용자가 퍼블릭 도메인으로 공개한 작품입니다. 이 공개 선언은 전세계적으로 유효합니다. 만약 저작권의 포기가 법률적으로 가능하지 않은 경우, Jim.belk 사용자는 이 작품을 법적으로 허용되는 한도 내에서 누구나 자유롭게 어떤 목적으로도 제한없이 사용할 수 있도록 허용합니다. .

Made with POVRay for Windows, version 3.6.

#include "colors.inc"

#declare AxisLength = 3;
#declare FrameWidth = 0.01;

global_settings { assumed_gamma 1.0}
plane { <0,0,1>, -0.5 pigment {color rgb <.9,.9,.9> } finish {ambient 0.4 diffuse 0.5} }
camera { location <0.1,0.5,4.5> sky <0,0,1> right <-1,1,0>/sqrt(2) look_at <0,0,0> }
light_source { <0, -2, 10> color White area_light <1, 0, 0>, <0, 1, 0>, 3, 3 adaptive 1 jitter }

#declare R = 1.5;  // radius to center circle of torus
#declare r = 0.5;  // radius of torus cross-section  
#declare r_tube = 0.1;  // thickness of tube
              
#macro tpoint(theta,phi)
  <(R + r*cos(phi))*cos(theta), (R + r*cos(phi))*sin(theta), r*sin(phi)>
#end

sphere_sweep
  {
  cubic_spline 35,
  #declare Index = 0;
  #while(Index < 35)
    tpoint( (Index-1)*pi/16, (Index-1)*pi/4), r_tube
    #declare Index = Index + 1;
  #end
  finish {phong 1} pigment {color Blue}
  }

sphere_sweep
  {
  cubic_spline 35,
  #declare Index = 0;
  #while(Index < 35)
    tpoint( (Index-1)*pi/16, (Index+3)*pi/4), r_tube
    #declare Index = Index + 1;
  #end
  finish {phong 1} pigment {color Red}
  }

Complied to 600 x 600, with 0.3 anti-aliasing